use AppleScript version "2.4" -- Yosemite (10.10) or later

use scripting additions



set DefLens to "SMC Pentax-A 24-50"



set theRespondedLens to the text returned of ¬

	(display dialog ¬

		"What's the lens used?" default answer DefLens ¬

		with icon note buttons {"Cancel", "Continue"} default button "Continue")

## in case there are multiple words in the Lens. But entering nothing will remove this Exif Tag

if 0 < length of theRespondedLens then set theRespondedLens to quoted form of theRespondedLens



set DefAperture to 4



set theRespondedAperture to the text returned of ¬

	(display dialog ¬

		"What's the aperture value?" default answer DefAperture ¬

		with icon note buttons {"Cancel", "Continue"} default button "Continue")

## Entering nothing will remove this Exif Tag from the file



set DefFocalLength to 24



set theRespondedFocalLength to the text returned of ¬

	(display dialog ¬

		"What's the focal length?" default answer DefFocalLength ¬

		with icon note buttons {"Cancel", "Continue"} default button "Continue")

## Entering nothing will remove this Exif Tag from the file

## Entering "0" will result in Capture One ignoring it



tell application "Capture One 11"

	set selectedVariants to get selected variants

	repeat with i from 1 to number of items in selectedVariants

		set this_item to item i of selectedVariants

		set theID to id of (parent image of this_item)

		

		## So that I can log it if necessary      

		set theExifToolCommand to ¬

			"/usr/local/bin/exiftool -overwrite_original_in_place -preserve -m " & ¬

			" -Lens=" & theRespondedLens & ¬

			" -FNumber=" & theRespondedAperture & ¬

			" -FocalLength=" & theRespondedFocalLength & ¬

			" " & quoted form of theID

		

		tell current application to do shell script theExifToolCommand

		

		##  Metadata tags which are removed from the image file will result in Capture One retaining the previous value.

		## There is no way to cause Capture One to remove a Metadata tag, once it has loaded it.

		reload metadata this_item

	end repeat

end tell